Package

flake.nix

@@ -0,0 +1,57 @@
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+  };
+
+  outputs =
+    { self, nixpkgs }:
+    let
+      systems = [
+        "x86_64-linux"
+        "aarch64-linux"
+        "x86_64-darwin"
+        "aarch64-darwin"
+      ];
+      forEachSystem =
+        f: nixpkgs.lib.genAttrs systems (system: f system (import nixpkgs { inherit system; }));
+    in
+    {
+      formatter = forEachSystem (_system: pkgs: pkgs.nixfmt-rfc-style);
+
+      packages = forEachSystem (
+        _system: pkgs:
+        let
+          mutannot = pkgs.buildDotnetModule {
+            pname = "mutannot";
+            version = "0.1.0";
+            src = ./Mutannot;
+            projectFile = "Mutannot.fsproj";
+            nugetDeps = ./Mutannot/deps.nix;
+            executables = [ "mutannot" ];
+            dotnet-sdk = pkgs.dotnet-sdk_10;
+            dotnet-runtime = pkgs.dotnet-sdk_10;
+            useDotnetFromEnv = true;
+
+            meta = {
+              mainProgram = "mutannot";
+            };
+          };
+        in
+        {
+          default = mutannot;
+          mutannot = mutannot;
+        }
+      );
+
+      devShells = forEachSystem (
+        _system: pkgs: {
+          default = pkgs.mkShell {
+            packages = [
+              pkgs.git
+              pkgs.dotnet-sdk_10
+            ];
+          };
+        }
+      );
+    };
+}